TIB: Source to Arcade.82P

TIB: Source to Arcade.82P

• To: TI-85 Basic <ti-basic@lists.ticalc.org>
• Subject: TIB: Source to Arcade.82P
• From: Christopher Robin MacDougald <crmacd@mail.utexas.edu>
• Date: Thu, 05 Feb 1998 20:28:15 -0600
• Reply-To: ti-basic@lists.ticalc.org

Sorry about that 85 posting... here are the 82 postings in ASCII. Enjoy!

\START82\
\COMMENT=4¥­Æ×8 file dated 07/19/97, 22:40
\NAME=ARCADE
\FILE=D:\PERSONAL\ARCADE.82P
:FullScreen
:ClrHome
:RectGC
:CoordOff
:GridOff
:AxesOff
:LabelOff
:FnOff 
:ZStandard
:ClrDraw
:Text(24,15,"ARCADE VERSION 2.0V"
:Text(30,12,"BY: CHRIS MACDOUGALD"
:Lbl A
:Menu("ARCADE GAMES 2.0","I.C. V6.3",B,"C.M. V2.1",E,"C.S.
V1.5",H,"EXI\#\
T",\@\
:Lbl B
:ClrDraw
:Menu("INTERNAL CALCBAT","PLAY",D,"",B,"HELP",C,"MENU",A
:Lbl C
:Text(0,37,"-HELP-"
:Text(6,2,"*TO WIN YOU MUST DEFEAT"
:Text(12,8,"YOUR OPPONENT."
:Text(18,2,"\deg\MOVE LT/RT: LT/RT ARROW"
:Text(24,2,"\deg\FIREBALL: UP ARROW"
:Text(30,2,"\deg\BLOCK: DOWN ARROW"
:Text(36,2,"\deg\HI/LOW KICK: MODE/X,T,\@\"
:Text(42,2,"\deg\HI/LOW PUNCH: 2ND/ALPHA"
:Text(48,2,"\deg\PAUSE: 8/ENTER  QUIT: 9"
:Text(57,27,"PRESS ENTER"
:Pause 
:Goto B
:Lbl D
:Split
:Text(0,13,"-TYPES OF GAMEPLAY-"
:Text(6,2,"1.)SINGLE MATCH"
:Text(12,2,"2.)TOURNAMENT"
:Repeat A\>=\1 and A\<=\2
:ClrHome
:Input "(1-2): ",A
:iPart A\->\A
:End
:A\^2\\->\A
:0\->\B
:0\->\C
:0\->\N
:0\->\O
:Repeat B\>=\A
:0\->\D
:0\->\L
:0\->\M
:B+1\->\B
:If A=1
:Then
:ClrDraw
:Text(0,15,"POSSIBLE OPPONENTS"
:Text(6,2,"1.)ANGULAR"
:Text(12,2,"2.)DICITOR"
:Text(18,2,"3.)HELLFIRE"
:Text(24,2,"4.)ULTRAMUS"
:Text(6,50,"5.)PRACTICE"
:Repeat C\>=\1 and C\<=\5
:ClrHome
:Input "(1-5): ",C
:iPart C\->\C
:End
:Else
:C+1\->\C
:End
:FullScreen
:Repeat D\>=\3
:99\->\E
:99\->\F
:100\->\G
:27\->\H
:61\->\I
:D+1\->\D
:ClrDraw
:Text(0,15,"-INTERNAL CALCBAT-"
:Text(24,31,"ROUND:",D,"/3"
:Text(30,30,"MATCH:",B,"/",A
:Text(57,27,"PRESS ENTER"
:Pause 
:ClrDraw
:Horizontal 5.7
:Horizontal \(-)\10
:Line(\(-)\5,\(-)\5.7,5,\(-)\5.7
:Line(\(-)\4,\(-)\5.7,\(-)\4,\(-)\10
:Line(4,\(-)\5.7,4,\(-)\10
:Text(0,1,"-P1-"
:Text(0,79,"CALC"
:Text(0,28,L
:Text(0,65,M
:Text(30,H,"O"
:Text(30,I+4,"O"
:Text(36,H,"\@\="
:Text(36,I,"=A"
:If C=2
:Text(36,I,"=D"
:If C=3
:Text(36,I,"=H"
:If C=4
:Text(36,I,"=U"
:If C=5
:Text(36,I,"=P"
:Text(42,H,"I>"
:Text(42,I+2,"<I"
:Repeat E\<=\0 or F\<=\0 or G\<=\1
:G-1\->\G
:Text(0,45,iPart G,"   "
:Text(6,5,E,"   "
:Text(6,83,F,"   "
:0\->\J
:getKey\->\J
:0\->\K
:If C\<=\4
:Then
:If C=1
:iPart 5rand+1\->\P
:If C=2
:iPart 10rand+1\->\P
:If C=3
:iPart 15rand+1\->\P
:If C=4
:iPart 21rand+1\->\P
:If P=11 or P=12 or P=18
:22\->\K
:If P=2 or P=14 or P=19
:32\->\K
:If P=8 or P=16
:21\->\K
:If P=9 or P=3
:31\->\K
:If P=6 or P=17
:26\->\K
:If P=4
:34\->\K
:If P=7
:25\->\K
:If P=5
:14\->\K
:If P=10
:15\->\K
:If P=15
:16\->\K
:If P=20
:17\->\K
:If P=21
:18\->\K
:If K=0
:26\->\K
:End
:If J=14
:Then
:Text(6,16,"COME HERE"
:Text(36,H+4,"<"
:For(\@\,H+7,I-5
:Text(36,\@\,"-\>=\"
:End
:If K\<>\34 and H+9<I
:Then
:Repeat H+9>I
:I-1\->\I
:Text(30,I,"<O"
:Text(36,I,"=X>"
:Text(42,I+2,"<I"
:End
:F-6\->\F
:Else
:E-3\->\E
:For(H,H,I-9)
:Text(30,H," O"
:Text(36,H," X="
:Text(42,H," I>"
:End
:End
:End
:If K=14 and I-9>H
:Then
:Text(6,48,"COME HERE"
:Text(36,I,">"
:I-8\->\\@\
:Repeat \@\\<=\H+3
:Text(36,\@\,"<-"
:\@\-1\->\\@\
:End
:If J\<>\34
:Then
:For(H,H,I-9)
:Text(30,H," O)"
:Text(36,H-3," (X="
:Text(42,H," I>"
:End
:E-7\->\E
:Else
:F-2\->\F
:Repeat H>I-10
:I-1\->\I
:Text(30,I+4,"O"
:Text(36,I,"=X"
:Text(42,I+2,"<I"
:End
:End
:End
:If J=15
:Then
:Text(6,16,"SUPER"
:F-2\->\F
:25\->\J
:End
:If K=15
:Then
:Text(6,48,"SUPER"
:E-3\->\E
:25\->\K
:End
:If K=16
:Then
:Text(6,48,"SUPER LP"
:E-3\->\E
:31\->\K
:End
:If K=17
:Then
:Text(6,48,"SUPER HP"
:E-3\->\E
:21\->\K
:End
:If K=18
:Then
:Text(6,48,"SUPER LK"
:E-3\->\E
:32\->\K
:End
:If J=21
:Then
:Text(30,H,"O/"
:Text(36,H-3,"(\@\   "
:If H+8\>=\I and K\<>\34
:F-2\->\F
:End
:If K=21
:Then
:Text(30,I,"L"
:Text(36,I,"    "
:Text(36,I+8,">"
:If I-8\<=\H and J\<>\34
:E-3\->\E
:End
:If J=22
:Then
:Text(30,H,"O)/"
:Text(36,H-3,"(\@\/"
:Text(42,H,"I   "
:If H+9\>=\I and K\<>\34
:F-3\->\F
:End
:If K=22
:Then
:Text(30,I,"I"
:Text(36,I,"X"
:Text(36,I+8,">"
:Text(42,I,"      I"
:If I-9\<=\H and J\<>\34
:E-4\->\E
:End
:If J=24
:H-1\->\H
:If K=24
:I+1\->\I
:If J=25
:Then
:Text(36,H+4,"<"
:If H+8<I
:Then
:Text(6,16,"FIREBALL"
:For(\@\,H+7,I-1
:Text(36,\@\," \^3\"
:End
:End
:If H+8\>=\I
:Then
:Text(6,16,"FIREWALL"
:H-1\->\H
:I+1\->\I
:E-1\->\E
:End
:If K\<>\34
:F-5\->\F
:End
:If K=25
:Then
:Text(36,I,">"
:If I-8>H
:Then
:Text(6,48,"FIREBALL"
:I-4\->\\@\
:Repeat H+4\>=\\@\
:Text(36,\@\,"\^2\"
:\@\-1\->\\@\
:End
:End
:If I-8\<=\H
:Then
:Text(6,48,"FIREWALL"
:H-1\->\H
:I+1\->\I
:F-1\->\F
:End
:If J\<>\34
:E-6\->\E
:End
:If J=26 and H+8\<=\I
:Then
:H+1\->\H
:If H+7\>=\I and K=0
:I+1\->\I
:End
:If K=26 and I-8\>=\H
:Then
:I-1\->\I
:If I-7\<=\H and J=0
:H-1\->\H
:End
:If J=31
:Then
:Text(36,H-3,"(\@\-"
:If H+8\>=\I and K\<>\34
:F-2\->\F
:End
:If K=31
:Then
:Text(36,I+8,">"
:Text(36,I,"-"
:If I-8\<=\H and J\<>\34
:E-3\->\E
:End
:If J=32
:Then
:Text(30,H,"O)"
:Text(36,H-3,"(\@\--"
:Text(42,H,"I   "
:If H+9\>=\I and K\<>\34
:F-4\->\F
:End
:If K=32
:Then
:Text(30,I,"<"
:Text(36,I-4,"--"
:Text(36,I+8,">"
:Text(42,I,"      I"
:If I-9\<=\H and J\<>\34
:E-5\->\E
:End
:If J=34
:Text(36,H,"\@\)"
:If K=34
:Text(36,I,"<"
:If J=73
:Then
:Text(18,37,"PAUSED"
:Pause 
:Text(18,37,"                       "
:End
:If J=74 or K=74
:Goto B
:If J\<>\0 or K\<>\0
:Then
:If J=21 or J=22 or J=32 or K=14
:Text(30,H+4,"   "
:If J=21 or J=22 or J=31 or J=32 or K=14
:Text(36,H-4,"   "
:If J=22
:Text(30,H+7,"   "
:If J=32
:Text(36,H+8,"   "
:If K=21 or K=22 or K=32 or J=14
:Text(30,I,"    "
:If K=21 or K=22 or K=31 or K=32 or J=14
:Text(36,I+8,"   "
:If K=32
:Text(36,I-4,"    "
:Text(30,H-1," O"
:Text(36,H-1," \@\="
:Text(42,H-1," I>"
:Text(30,I+3," O"
:Text(36,I-1," =A"
:If C=2
:Text(36,I-1," =D"
:If C=3
:Text(36,I-1," =H"
:If C=4
:Text(36,I-1," =U"
:If C=5
:Text(36,I-1," =P"
:Text(42,I+1," <I"
:End
:If H<23
:\(-)\20\->\E
:If I>65
:\(-)\20\->\F
:End
:If D=3 and L>M
:Then
:Text(18,3,"DON'T LOOK UP... THAT'S ONE"
:Text(24,10,"BIG SAFE! PRESS ENTER."
:Text(30,I,"+-+"
:Text(36,I," I\deg\ I"
:Text(42,I,"+-+"
:Pause 
:End
:ClrDraw
:If E>F and E\<>\F
:Then
:L+1\->\L
:Text(24,34,"PLAYER 1"
:Else
:M+1\->\M
:Text(24,28,"CALCULATOR"
:End
:Text(0,15,"-ROUND: ",D," RESULTS-"
:Text(30,40,"WINS"
:Text(57,27,"PRESS ENTER"
:Pause 
:End
:Text(36,38,"FIGHT!"
:If L>M
:Then
:Text(24,28,"      PLAYER 1     "
:N+1\->\N
:Else
:Text(24,28,"CALCULATOR"
:O+1\->\O
:End
:Pause 
:End
:If B\>=\4
:Then
:Text(36,26,"TOURNAMENT"
:If N>O
:Then
:Text(24,28,"      PLAYER 1     "
:Else
:Text(24,28,"CALCULATOR"
:End
:Pause 
:End
:Goto B
:Lbl E
:ClrDraw
:{1,1}\->\dim [E]
:Menu("CALCULATOR MAN  ","PLAY",G,"",E,"HELP",F,"MENU",A
:Lbl F
:Text(0,37,"-HELP-"
:Text(6,2,"*YOU  MUST COLLECT ALL OF"
:Text(12,8,"THE PELLETS TO WIN, BUT"
:Text(18,8,"YOU MUST ALSO AVOID THE"
:Text(24,8,"GHOST."
:Text(30,2,"\deg\MOVE AROUND: ARROW KEYS"
:Text(36,2,"\deg\PAUSE: 8/ENTER  QUIT: 9"
:Text(57,27,"PRESS ENTER"
:Pause 
:Goto E
:Lbl G
:0\->\A
:{7,15}\->\dim [E]
:Repeat A>90
:Fill(0,[E]
:A+10\->\A
:ClrDraw
:Text(0,17,"-CALCULATOR MAN-"
:Text(24,30,"THINKING..."
:0\->\D
:Repeat D=A
:iPart (7)rand+1\->\B
:iPart (15)rand+1\->\C
:If [E](B,C)\<>\1
:Then
:D+1\->\D
:1\->\[E](B,C
:End
:End
:Text(24,30,"LEVEL: ",A/10,"           "
:Text(57,27,"PRESS ENTER"
:Pause 
:ClrDraw
:Horizontal \(-)\10
:Text(0,2,"PELLETS: "
:Horizontal 7.7
:Vertical \(-)\10
:Vertical 10
:Line(5.3,7.7,5.3,10
:Line(3.6,7.7,3.6,10)
:For(E,28,38
:Pxl-Off(E,0
:Pxl-Off(E,94
:End
:For(B,1,7
:For(C,1,15
:If [E](B,C)=1
:Pxl-On((B*7)+9,6*C)
:End
:End
:8\->\B
:2\->\C
:0\->\E
:1\->\F
:65\->\G
:Repeat E=A
:Text(0,32,E,"/",A
:Text(B,C,"    "
:Text(F,G,"     "
:0\->\I
:getKey\->\I
:If I=24 or I=25 or I=26 or I=34
:I\->\D
:If D=25 and B>8
:Then
:B-1\->\B
:If pxl-Test(B,C)=1 or pxl-Test(B,C+1)=1 or pxl-Test(B,C+2)=1 or
pxl-Te\#\
st(B,C+3)=1
:E+1\->\E
:End
:If D=34 and B<55
:Then
:B+1\->\B
:If pxl-Test(B+5,C)=1 or pxl-Test(B+5,C+1)=1 or pxl-Test(B+5,C+2)=1 or
\#\
pxl-Test(B+5,C+3)=1
:E+1\->\E
:End
:If D=24 and C>2
:Then
:C-1\->\C
:If pxl-Test(B,C)=1 or pxl-Test(B+1,C)=1 or pxl-Test(B+2,C)=1 or
pxl-Te\#\
st(B+3,C)=1 or pxl-Test(B+4,C)=1 or pxl-Test(B+5,C)=1
:E+1\->\E
:End
:If D=24 and C\<=\2 and B\>=\28 and B\<=\32
:89\->\C
:If D=26 and C<90
:Then
:C+1\->\C
:If pxl-Test(B,C+3)=1 or pxl-Test(B+1,C+3) or pxl-Test(B+2,C+3)=1 or
px\#\
l-Test(B+3,C+3) or pxl-Test(B+4,C+3) or pxl-Test(B+5,C+3)=1
:E+1\->\E
:End
:If D=26 and C\>=\90 and B\>=\28 and B\<=\32
:2\->\C
:Text(B,C,"C"
:If B<F and pxl-Test(F-1,G)\<>\1 and pxl-Test(F-1,G+1)\<>\1 and
pxl-Tes\#\
t(F-1,G+2)\<>\1 and pxl-Test(F-1,G+3)\<>\1 and pxl-Test(F-1,G+4)\<>\1
a\#\
nd pxl-Test(F-1,G+5)\<>\1
:F-1\->\F
:If B>F and pxl-Test(F+6,G)\<>\1 and pxl-Test(F+6,G+1)\<>\1 and
pxl-Tes\#\
t(F+6,G+2)\<>\1 and pxl-Test(F+6,G+3)\<>\1 and pxl-Test(F+6,G+4)\<>\1
a\#\
nd pxl-Test(F+6,G+5)\<>\1
:F+1\->\F
:If G>C and B=F and pxl-Test(F,G-1)\<>\1 and pxl-Test(F+1,G-1)\<>\1
and\#\
 pxl-Test(F+2,G-1)\<>\1 and pxl-Test(F+3,G-1)\<>\1 and
pxl-Test(F+4,G-1\#\
)\<>\1 and pxl-Test(F+5,G-1)\<>\1
:G-1\->\G
:If G<C and B=F and pxl-Test(F,G+6)\<>\1 and pxl-Test(F+1,G+6)\<>\1
and\#\
 pxl-Test(F+2,G+6)\<>\1 and pxl-Test(F+3,G+6)\<>\1 and
pxl-Test(F+4,G+6\#\
)\<>\1 and pxl-Test(F+5,G+6)\<>\1
:G+1\->\G
:Text(F,G,"\pi\"
:If (C=G-4 or C=G+5) and B=F
:Then
:Text(24,30,"GAME OVER"
:Text(30,27,"PRESS ENTER"
:Pause 
:74\->\I
:End
:If I=73
:Then
:Text(0,74,"PAUSE"
:Pause 
:Text(0,74,"                   "
:End
:If I=74
:Goto E
:If E=A/2
:Then
:For(H,65,71
:Pxl-Off(7,H
:End
:End
:End
:End
:Goto E
:Lbl H
:ClrDraw
:Menu("CALCULATOR SNAKE","PLAY",J,"",H,"HELP",I,"MENU",A
:Lbl I
:Text(0,37,"-HELP-"
:Text(6,2,"*YOU MUST COLLECT ALL OF"
:Text(12,8,"THE APPLES(DOTS) WITH-"
:Text(18,8,"OUT HITTING THE WALLS."
:Text(24,2,"\deg\MOVE AROUND: ARROW KEYS"
:Text(30,2,"\deg\PAUSE: 8/ENTER  QUIT: 9"
:Text(57,27,"PRESS ENTER"
:Pause 
:Goto H
:Lbl J
:0\->\A
:Repeat A\>=\10
:A+1\->\A
:A*2\->\B
:0\->\C
:2\->\D
:2\->\E
:Text(0,9,"-CALCULATOR SNAKES-"
:Text(24,32,"LEVEL:",A
:Text(30,30,"APPLES:",B
:Text(57,27,"PRESS ENTER"
:Pause 
:ClrDraw
:Horizontal 10
:Vertical 10
:Horizontal \(-)\10
:Vertical \(-)\10
:Line(5.3,7.5,10,7.5
:Line(5.3,7.5,5.3,10
:If A=1 or A=5 or A=7 or A=9
:Line(\(-)\5,0,5,0
:If A=3 or A=5 or A=7
:Then
:Line(\(-)\5,5,5,5
:Line(\(-)\5,\(-)\5,5,\(-)\5
:End
:If A=2 or A=6 or A=8 or A=9
:Line(0,5,0,\(-)\5
:If A=4 or A=6 or A=8 or A=9
:Then
:Line(\(-)\5,5,\(-)\5,\(-)\5
:Line(5,5,5,\(-)\5
:End
:If A=7
:Then
:Line(\(-)\5,\(-)\5,\(-)\5,0
:Line(5,0,5,5
:End
:If A=8
:Then
:Line(0,5,5,5
:Line(0,\(-)\5,\(-)\5,\(-)\5
:End
:If A=10
:Then
:Circle(0,0,4
:Circle(0,0,8
:Text(6,45,"      "
:Text(18,45,"      "
:Text(42,45,"      "
:Text(54,45,"      "
:End
:26\->\G
:0\->\H
:9\->\I
:9\->\J
:Repeat H\<>\0 and (pxl-Test(D,E)=1 or B=C)
:Pxl-On(D,E
:Text(1,74,C,"/",B,"       "
:If H=0
:Then
:iPart (58)rand+1\->\I
:iPart (88)rand+1\->\J
:If pxl-Test(I-1,J)\<>\1 and pxl-Test(I+1,J)\<>\1 and
pxl-Test(I,J-1)\<>\\#\
1 and pxl-Test(I,J+1)\<>\1 and I\>=\9 and J\<=\72
:Then
:Pxl-On(I,J)
:1\->\H
:End
:End
:0\->\F
:getKey\->\F
:If F=24 or F=25 or F=26 or F=34
:F\->\G
:If G=24
:E-1\->\E
:If G=25
:D-1\->\D
:If G=26
:E+1\->\E
:If G=34
:D+1\->\D
:If F=73
:Then
:Text(1,74,"PAUSE"
:Pause 
:End
:If F=74
:Goto H
:If D=I and E=J
:Then
:C+1\->\C
:0\->\H
:End
:End
:If B\<>\C
:Then
:Text(24,30,"GAME OVER"
:Text(30,27,"PRESS ENTER"
:Pause 
:Goto H
:End
:ClrDraw
:End
:Goto H
:Lbl \@\
:FullScreen
:ClrDraw
:FnOn 
:RectGC
:CoordOn
:GridOff
:AxesOn
:LabelOff
:ZStandard
:ClrHome
\STOP82\

• TIB: Boolean statments..(BJE)
• From: Bill James Ellis <B.J.Ellis@hw.ac.uk>

• Prev: Re: TIB: HAL
• Next: TIB: Source to Sports.82P
• Index(es):
  • Main
  • Thread