; SnapShot
; by Randy Gluvna
; randyg@freenet.tlh.fl.us

.include "asm86.h"
.include "ti86asm.inc"
.include "ti86abs.inc"
.org _asm_exec_ram

        call _clrLCD
        ld hl,$0000
        ld (_curRow),hl
        set 3,(iy+05)
        ld hl,_str_title
        call _puts
        res 3,(iy+05)
        ld hl,$0003
        ld (_curRow),hl
        ld hl,_str_menu
        call _puts       
KEY_LOOP:
        call _getkey
        cp k1
        jr z,ENABLE
        cp k2
        jr z,DISABLE
        cp kExit
        jr z,EXIT
        cp kClear
        jr z,EXIT
        jr KEY_LOOP
ENABLE:
        ld hl,__INT__
        ld de,$D2FE
        ld bc,__INT_END-__INT__+1
        ldir
        ld a,($D2FE)
        ld hl,$D325
        add a,(hl)
        ld hl,$D34D
        add a,(hl)
        ld hl,$D375
        add a,(hl)
        ld hl,$D39D
        add a,(hl)
        ld hl,$D3C5
        add a,(hl)
        ld ($D2FD),a
        set 2,(iy+$23)
        jr EXIT        
DISABLE:
        res 2,(iy+$23)       
EXIT:
        ld hl,$0000
        ld (_curRow),hl
        jp _clrLCD

__INT__:
        in a,(3)
        and 8
        ret nz
        res 4,(iy+9)
        ld c,5
        in d,(c)
        ld a,$0D
        out (5),a
        ld c,6
        in e,(c)
        push de
        ld hl,_var_pict-__INT__+$D2FE
        rst 20h
        rst 10h
        call c,_CREATEPICT
        ex de,hl
        ld a,b
        call _load_ram_ahl
        ex de,hl
        inc de
        inc de
        ld hl,$FC00      
        ld bc,1008
        ldir
        pop de
        ld c,5
        out (c),d
        ld c,6
        out (c),e
        ret
_var_pict:
        .db $11,8,"SnapShot"

__INT_END:

_str_title:
        .db "      Snap shot      "
        .db "   by Randy Gluvna   ",0

_str_menu:
        .db "     1: Enable       "
        .db "     2: Disable",0

.end