;Memview 1.1
;This program was written by Alan Bailey.  Use it any way you wish, but it would
;be cool if you would give me some credit.  The buttons to use are +,-,*,/,<, and >.
;This was compiled using Asm86 v1.0, also written by me, available at ticalc.org
;
;Alan Bailey
;bailala@mw.sisna.com           <try this one first, if no reply by 3 days, try next
;bailela@charlie.cns.iit.edu    <try this one second, if no reply by 3 days, try next
;ebailey@kiwi.dep.anl.gov       <try this one last, if no reply by 3 months, I died
;
;http://www.mw.sisna.com/users/bailala/
;
;IRC: Abalone on #calc-ti, EFnet occasionally
;
;Copyright (C) 1997 Alan Bailey


#include "asm86.h"         ;If you use Asm86(and you should), put this header first
#include "ti86asm.inc"

#DEFINE  CALL_(addr)     in a,(5) \ push af \ ld a,%00001101 \ out (5),a \ call addr \ pop af \ out (5),a
			  ;needed because of changing rom pages


.org $D748


	in a,(5)
	push af
	in a,(6)
	push af
	CALL_(_clrLCD)
    call showscreen

keyloop:
    call GET_KEY          ;the REAL getkey
    cp K_EXIT
    jr z,exittime
    cp K_UP
    jr z,downgo
    cp K_DOWN
    jr z,upgo
    cp K_PLUS
    jp z,bigupgo
    cp K_MINUS
    jr z,bigdowngo
    cp K_STAR              ;mult
    jr z,biggerupgo
    cp K_SLASH              ;div
    jr z,biggerdowngo
	cp K_F2
	jp z,romright
	cp K_F1
	jp z,romleft
	cp K_F4
	jp z,ramleft
	cp K_F5
	jp z,ramright
	cp K_ALPHA
	jp z,changealpha
    jr keyloop


exittime:
    CALL_(_clrLCD)
	pop af
	out (6),a
	pop af
	out (5),a
    ret


downgo:
    ld hl,(SETADDRESS)
    ld bc,$0008
    or a                    ;clear carry
    sbc hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jr keyloop

upgo:
    ld hl,(SETADDRESS)
    ld bc,$0008
    add hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jr keyloop

biggerdowngo:
    ld hl,(SETADDRESS)
    ld bc,$1000
    or a
    sbc hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jr keyloop

biggerupgo:
    ld hl,(SETADDRESS)
    ld bc,$1000
    add hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jp keyloop

bigdowngo:
    ld hl,(SETADDRESS)
    ld bc,$0100
    or a
    sbc hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jp keyloop

bigupgo:
    ld hl,(SETADDRESS)
    ld bc,$0100
    add hl,bc
    ld (SETADDRESS),hl
    call showscreen
    jp keyloop               ;no need for JUMP_(), yahoo!!

romleft:
	in a,(5)
	dec a
	and %00001111
	out (5),a
	call showscreen
	jp keyloop

romright:
	in a,(5)
	inc a
	and %00001111
	out (5),a
	call showscreen
	jp keyloop

ramleft:
	in a,(6)
	res 6,a
	dec a
	and %00000111
	set 6,a
	out (6),a
	call showscreen
	jp keyloop

ramright:
	in a,(6)
	res 6,a
	inc a
	and %00000111
	set 6,a
	out (6),a
	call showscreen
	jp keyloop

changealpha:
	ld a,(ALPHA)
	xor %00000001
	ld (ALPHA),a
	CALL_(_clrLCD)
	call showscreen
	jp keyloop

showscreen:
	ld a,(ALPHA)
	or a
	call nz,showclearfirst

    ld hl,$394e
    ld (_penCol),hl
    ld hl,words
    CALL_(_vputs)

	ld hl,$3905
	ld (_penCol),hl
	ld hl,words2
    CALL_(_vputs)

	ld hl,$391d
	ld (_penCol),hl
	ld hl,words3
    CALL_(_vputs)

	ld hl,$392e			;ram page
	ld (_penCol),hl
	in a,(6)
	or a
	call getascii
	ld (putchar),a
	ld hl,putchar
    CALL_(_vputs)

	ld hl,$3916			 ;this does the rom page
	ld (_penCol),hl
	in a,(5)
	or a				;complement carry flag for low nibble
	call getascii
	ld (putchar),a
	ld hl,putchar
	CALL_(_vputs)

    ld hl,$0000
    ld (COORDS),hl

    ld hl,(SETADDRESS)
    ld (MOVEADDRESS),hl
    ld b,8
showscreen2:
    push bc
    ld hl,(COORDS)
    ld (_penCol),hl
    ld hl,(MOVEADDRESS)
    call putword                ;puts out the offset
    ld hl,_penCol
    ld a,3
    add a,(hl)
    ld (hl),a
    call displayrow
    ld hl,(COORDS)
    ld bc,$0700
    add hl,bc
    ld (COORDS),hl          ;moveaddress already set
    pop bc
    djnz showscreen2
    ret

showclearfirst:
	CALL_(_clrLCD)		;this is the bug from v1.0, I called _vputs instead
    ret


displayrow:
    ld b,4
    ld hl,(MOVEADDRESS)
displayrow2:
    push bc
    push hl
    call LD_HL_MHL     ;LD_HL_MHL
    ld a,l
    ld l,h
    ld h,a
    call putword            ;puts the word just gotten
    pop hl
    inc hl
    inc hl
    pop bc
    djnz displayrow2
	ld a,(ALPHA)
	or a
	jr z,displayrow3
	push hl
	ld hl,_penCol
	inc (hl)
	ld hl,(MOVEADDRESS)
	ld de,putascii
	ld bc,8					;move the row into the space
	ldir
	ld hl,putascii
	ld b,8
	CALL_(_vputsn)
	pop hl			  ;the saved new moveaddress
displayrow3:			;goes here if wants to skip alpha stuff
    ld (MOVEADDRESS),hl
    ret


putword:            ;hl contains word to put, _penRow should be set
    push hl
    ld a,h
    call putbyte
    pop hl
    ld a,l
    call putbyte
    ret

putbyte:
    push af
    scf
    call getascii
    ld (putchar),a
    ld hl,putchar
	CALL_(_vputs)
    pop af
    or a
    call getascii
    ld (putchar),a
    ld hl,putchar
	CALL_(_vputs)
    ret

                                ;       a contains byte
getascii:               ;carry flag  0 - get low nibble  1 - get high nibble
    call c,getasciihigh
getasciilow
    and %00001111           ;mask out 
    ld b,a
    ld c,6
    add a,c                 ;6-21, with 16 being $0A
    bit 4,a
    jr nz,gethexchar
    jr getnormnum

getasciihigh:
    rra
    rra
    rra
    rra
    ret

gethexchar:             ;number either $a,b,c,d,e,f
    ld a,b          ;
    sub $0A            ;gets offset starting at 0
    add a,'A'       ;adds to get ascii code
    ret
getnormnum:             ;number either $0,1,2,3,4,5,6,7,8,9
    ld a,b
    add a,'0'       ;offset of '0', $30
    ret             ;returns with correct ascii code


putchar:
    .db $00,$00        ;I don't know the call to put one char...yet

putascii:
	.db $00,$00,$00,$00,$00,$00,$00,$00

words:
    .db "By: Alan Bailey",0

words2:
	.db "ROM: ",0
words3:
	.db "RAM: ",0



SETADDRESS:              ;put variables in your programs, and can initialize here
    .dw $0000
MOVEADDRESS:
    .dw $0000
COORDS:
    .dw $0000
ALPHA:
	.db $00



.end