; MemEdit 82 v1.0
; by Randy Gluvna
; gluvna@home.com
; http://members.home.com/gluvna

#INCLUDE "TI82.H"

.ORG START_ADDR

.DB "MemEdit82 v1.0",0

        ROM_CALL(CLEARLCD)
        LD HL,$0000
        LD (CURSOR_ROW),HL
        LD HL,STRING_TITLE
        SET 3,(IY+05)
        ROM_CALL(D_ZT_STR)
        LD HL,$0001
        LD (CURSOR_ROW),HL
        LD HL,STRING_AUTHOR
        RES 3,(IY+05)
        ROM_CALL(D_ZT_STR)
        LD HL,$0003
        LD (CURSOR_ROW),HL
        LD HL,STRING_ADDRESS
        ROM_CALL(D_ZT_STR)
        LD HL,$0004
        LD (CURSOR_ROW),HL
        LD HL,STRING_CONTENTS
        ROM_CALL(D_ZT_STR)
        LD HL,$0005
        LD (CURSOR_ROW),HL
        LD HL,STRING_ASCII
        ROM_CALL(D_ZT_STR)
        LD HL,$0006
        LD (CURSOR_ROW),HL
        LD HL,STRING_ROM_PAGE
        ROM_CALL(D_ZT_STR)
        LD HL,$0000
LOOP:
        PUSH HL
        LD HL,$0903
        LD (CURSOR_ROW),HL
        POP HL
        LD A,H
        CALL D_A_HEX
        LD A,L
        CALL D_A_HEX
        LD A,4
        PUSH HL
        ROM_CALL(TX_CHARPUT)
        LD HL,$0A04
        LD (CURSOR_ROW),HL
        POP HL
        LD A,(HL)
        CALL D_A_HEX
        LD A,4
        PUSH HL
        ROM_CALL(TX_CHARPUT)
        LD HL,$0705
        LD (CURSOR_ROW),HL
        POP HL
        LD A,(HL)
        CP $D6
        JR NZ,NON_NL
        LD A,$3A
NON_NL:
        PUSH HL
        ROM_CALL(TX_CHARPUT)
        LD HL,$0A06
        LD (CURSOR_ROW),HL
        IN A,(2)
        AND 7
        CALL D_A_HEX_0
        LD A,4
        ROM_CALL(TX_CHARPUT)
        CALL GET_KEY
        POP HL
        CP 55
        JR Z,QUIT
        CP 53
        JR Z,ROM_DEC
        CP 52
        JR Z,ROM_INC
        CP 4
        JR Z,MEM_INC
        CP 1
        JR Z,MEM_DEC
        CP 10
        JR Z,MEM_INC_100
        CP 11
        JR Z,MEM_DEC_100
        CP 12
        JR Z,MEM_INC_1000
        CP 13
        JR Z,MEM_DEC_1000
        CP 3
        JR Z,ALTER_INC
        CP 2
        JR Z,ALTER_DEC
        JP LOOP
ROM_DEC:
        IN A,(2)
        CP 136
        JP Z,LOOP
        DEC A
        OUT (2),A
        JP LOOP
ROM_INC:
        IN A,(2)
        CP 143
        JP Z,LOOP
        INC A
        OUT (2),A
        JP LOOP
MEM_INC:
        INC HL
        JP LOOP
MEM_DEC:
        DEC HL
        JP LOOP
MEM_INC_100:
        LD DE,$0100
        ADD HL,DE
        JP LOOP
MEM_DEC_100:
        LD DE,$0100
        OR A
        SBC HL,DE
        JP LOOP
MEM_INC_1000:
        LD DE,$1000
        ADD HL,DE
        JP LOOP
MEM_DEC_1000:
        LD DE,$1000
        OR A
        SBC HL,DE
        JP LOOP
ALTER_INC:
        INC (HL)
        JP LOOP
ALTER_DEC:
        DEC (HL)
        JP LOOP
QUIT:
        ROM_CALL(CLEARLCD)
        LD HL,$0000
        LD (CURSOR_ROW),HL
        RET
D_A_HEX:
        PUSH AF
        SRL A
        SRL A
        SRL A
        SRL A
        CALL D_A_HEX_0
        POP AF
        AND 15
        CALL D_A_HEX_0
        RET
D_A_HEX_0:
        SUB 10
        JR C,D_A_HEX_1
        ADD A,7
D_A_HEX_1:
        ADD A,58
        PUSH HL
        ROM_CALL(TX_CHARPUT)
        POP HL
        RET

STRING_TITLE:
        .DB "MemEdit 82  v1.0",0
STRING_AUTHOR:
        .DB "by Randy Gluvna",0
STRING_ADDRESS:
        .DB "Address:",0
STRING_CONTENTS:
        .DB "Contents:",0
STRING_ASCII:
        .DB "ASCII:",0
STRING_ROM_PAGE:
        .DB "ROM Page:",0
.END